! csigalépcső 2.2
! Kiss Zsolt
!-------------------------------
! lépcső járólapok
!-------------------------------
PEN pen3d
RESOL 72
IF gyam="nincs" THEN ng =0
IF gyam="lemez" THEN
gb=b_kar
gcb=0
gck=0
ng=1
ENDIF
IF gyam="gerenda középen" THEN
gcb=(b_kar-gb)/2
ng=1
ENDIF
lvy0 = lv/COS(ATN(m/(r_orso+b_kar)*alfa/180*PI))
IF gck THEN lvy0=.03
IF gyam="oszlop" THEN
oszlop=1
v=m
ng=0
lvy0=.03
ENDIF
IF tomor THEN v=m
ROTZ alfa/2
ADDZ m-v
FOR i=0 TO n-1
CPRISM_ mat,mat,mat,
8,v,
-r_orso*x, r_orso*y,15,
-(r_orso+b_kar)*x, (r_orso+b_kar)*y,15,
0,0,900,
(r_orso+b_kar)*x, (r_orso+b_kar)*y,3000+15,
r_orso*x, r_orso*y,15,
0,0,900,
r_orso,alfa-oszlop*360,4000,
-r_orso*x, r_orso*y,1
ADD -0.015, r_orso+b_kar,-lvy0
MATERIAL m_korlatoszlop
BLOCK .03,.03,.95+v+lvy0
DEL 1
ROTZ alfa
ADDZ m
NEXT i
!--------------------------------------------
IF ng > 0 THEN
IF ng > 1 THEN dr=(b_kar-gb-gcb-gck)/(ng-1)
r0=r_orso+gcb+gb
FOR j=0 TO ng-1
DEL TOP
r = r0 + j*dr
szk = r*alfa/180*PI
beta = ATN(m/szk)
lvx= lv/SIN(beta)
lvy = lv/COS(beta)
FOR i=0 TO n-1
PUT i*szk, (i+1)*m-v,15
PUT (i+1)*szk, (i+1)*m-v,15
NEXT i
ROTZ 180
ADDY -r
ROTX 90
BPRISM_ gm,gm,gm,
5+2*n, -gb, r,
lvx+v/m*szk,0,15,
lvx+v/m*szk,-ca,15,
0,-ca,15,
GET (n*2*3),
n*szk,n*m-lvy,15,
lvx+v/m*szk,0,-1
NEXT j
ENDIF
! --------------- KORLÁT -----------------
DEL TOP
ROTX 90
ROTY 180
ADDZ (r_orso + b_kar)
khx = n*(r_orso + b_kar)*alfa/180*PI
FOR i = 1 to 3
khi=i*.25
BPRISM_ km,km,km,
5, -.02, r_orso+b_kar,
0, khi,15,
0, khi+.1,15,
khx,n*m+khi+.10,15,
khx,n*m+khi,15,
0, khi,-1
NEXT i
ADDZ .04
kfhx = n*(r_orso + b_kar+.04)*alfa/180*PI
BPRISM_ km,km,km,
5, -.07, r_orso+b_kar+.04,
0,.95+m/2,15,
0,1+m/2,15,
kfhx,n*m+1+m/2,15,
kfhx,n*m+.95+m/2,15,
0,.95+m/2,-1
|
3d tolla (szinezett kontúros rajz esetén)
A felbontás legyen a kör hetvenkettede
A lv külső íven mért függőleges komponense
Ha tömör a 'lépcső' legyen a v=m
Forgassuk el KR-t (így az induló él Y irányú)
az első lépcsőfok alja m-v magasságban
ciklus i nullától nő (n-1)-ig
a CPRISM_ anyagai a tetején, alján, oldalán
alappoligonja 8 pont ,v vastag,
x1, y1,maszk1,
x2, y2,maszk2,
középpont x, y,
x3, y3,maszk3,
x4, y4,maszk4,
középpont x, y,
sugár, alfa, maszk
x5, y5,maszk5
KR* eltolása a
általános anyag (korlátoszlop) beállítása
korlátoszlop (egy téglatest) elhelyezése
utolso KR* transzformáció törlése
KR* elforgatása Z körül alfával
KR* felemelése Z mentén m-mel
ciklus vége
*KR : koordinátarendszer
dr: gerendák tengelytávolsága
az első gerenda külső ívének sugara
ciklus 0-tól (gerendák száma - 1)-ig
Összes koordináta-transzformáció törlése
az aktuális gerenda külső ívének sugara
az itt mért belépés szélesség
az itt mért meredekség
a gerenda vízszintes metszete
a gerenda függőleges metszete
ciklus 0-tól (lépcsőfokok száma-1)-ig
A verembe helyezem az i-edik lépcsőfok,
majd az i+1-edik lépcsőfok koordinátáját
5 egyedi pont + fokonként két pont
1. egyedi pont
2. egyedi pont
3. egyedi pont
A veremből kiolvasok fokonként két pontot
három-három értékével (x,y,maszk)
4. egyedi pont
Az 1. pont a bezárásához (maszk=-1)
ciklus vége
feltétel vége
összes KR* transzformáció törlése
KR* elforgatása
KR* elforgatása
KR* eltolása a sugárral
a korlát hossza a külső íven
ciklus kezdete
korlát alsó z koordinátája
korlátelem
ciklus vége
KR* eltolása a sugárkülönbséggel
a fogodzó hossza hossza a külső íven
|
