! lesarkított ablak 2D 1.0
!
! Kiss Zsolt
!-------------------------------
PEN SYMB_SECT_PEN
IF GLOB_SCALE >= 100 THEN
RECT2 a/2,0,a/2-ts,-tv
RECT2 -a/2,0,-(a/2-ts),-tv
PEN p_nezet
LINE2 -(a/2-ts),0,(a/2-ts),0
LINE2 -(a/2-ts),-tv,(a/2-ts),-tv
LINE2 -(a/2-ts),-tv/2,(a/2-ts),-tv/2
ELSE
SET FILL SYMB_FILL
FOR i=1 TO 2
POLY2_B 9,3,
SYMB_FILL_PEN, SYMB_FBGD_PEN,
a/2,0,1,
a/2-ts,0,1,
a/2-ts,-tv/3,1,
a/2-ts+0.015,-tv/3,1,
a/2-ts+0.015,-2*tv/3,1,
a/2-ts+0.03,-2*tv/3,1,
a/2-ts+0.03,-tv,1,
a/2,-tv,1,
a/2,0,-1
POLY2_B 5,3,
SYMB_FILL_PEN, SYMB_FBGD_PEN,
a/2-ts+0.045,-tv, 1,
a/2-ts+0.045,-4*tv/3, 1,
a/2-ts+0.045-.08,-4*tv/3, 1,
a/2-ts+0.045-.08,-tv/3, 1,
a/2-ts,-tv/3 , 1
MUL2 -1,1
NEXT i
DEL 1
PEN p_nezet
LINE2 -(a/2-ts),0,a/2-ts,0
FOR i= 1 TO 4
LINE2 -(a/2-ts+0.045-.08),-i*tv/3,
a/2-ts+0.045-.08, -i*tv/3
NEXT i
ENDIF
|
toll beállítása
ha a lépték 100, vagy nagyobb, akkor
tok jobb
tok bal
toll (nézetvonal
tok vonalai
.
.
egyébként
kitöltés=metszett kitöltés
ciklus (bal és jobb tok)
tok poligon 9 ponttal, ,
kitöltés, kitöltés háttérszín,
x1, y1, maszk1,
x2, y2, maszk2,
.
.
.
.
.
.
x9, y9, maszk9
szárny poligon 5 ponttal, ,
kitöltés, kitöltés háttérszín,
x1, y1, maszk1,
x2, y2, maszk2,
.
.
x5, y5, maszk5
tükrözés x irányban
ciklus vége
egy KR transzformáció törlés
nézet tol beállítása
vonal
ciklus 1 - 4-ig
vonal
ciklus vége
feltétel vége
|
! ! lesarkított ablak 2D 1.0
! Kiss Zsolt
!----------------
! lyuk a falban
! ---------------
WALLHOLE 7, 1,
-a/2 , 0 , 15,
-a/2 , b-d , 15,
-a/2+c , b , 15,
a/2-c , b , 15,
a/2 , b-d , 15,
a/2 , 0 , 15,
-a/2 , 0 , 15
! ---------------
! tok
! ---------------
TUBE 9,9,127,
0,0,0,
ts,0,0,
ts,tv/3,0,
ts-0.016,tv/3,0,
ts-0.016,2*tv/3,0,
ts-0.031,2*tv/3,0,
ts-0.031,tv,0,
0,tv,0,
0,0,0,
-a/2,b,0,0,
-a/2,0,0,0,
a/2,0,0,0,
a/2,b-d,0,0,
a/2-c,b,0,0,
-a/2+c,b,0,0,
-a/2,b-d,0,0,
-a/2,0,0,0,
a/2,0,0,0
! ---------------
! szárny
! ---------------
ADD -(a/2-(ts-0.06)),0,tv+tv/6
!----vasalat ----
ROTX -90
ADDZ (b-d)/4
MATERIAL vasalat
CYLIND .05,.01
ADDZ (b-d)/2
CYLIND .05,.01
DEL 3
!----------------
MATERIAL fa
ROTY -alfa
ADD a/2-(ts-0.06),0,-(tv+tv/6)
TUBE 9,9,127,
ts-0.045,tv,1,
ts-0.045,4*tv/3,1,
ts-0.045+.08,4*tv/3,1,
ts-0.045+.08,1*tv/3,1,
ts-0.014,1*tv/3,1,
ts-0.014,2*tv/3,1,
ts-0.029,2*tv/3,1,
ts-0.029,3*tv/3,1,
ts-0.044,tv,1,
-a/2,b,0,0,
-a/2,0,0,0,
a/2,0,0,0,
a/2,b-d,0,0,
a/2-c,b,0,0,
-a/2+c,b,0,0,
-a/2,b-d,0,0,
-a/2,0,0,0,
a/2,0,0,0
!---------------------------
! üvegezés
!---------------------------
ub=(ts-0.045+.08)
gamma=ATN(c/d)
aa=a-2*ub
bb=b-2*ub
cc=c-(1-TAN(gamma/2))*ub
dd=d-(1-TAN(45-gamma/2))*ub
ADDZ tv/3*2.5-.01
ADDY ub
CPRISM_ uveg,uveg,uveg,
7,0.02,
-aa/2, 0, 15,
-aa/2, bb-dd, 15,
-aa/2+cc, bb, 15,
aa/2-cc, bb, 15,
aa/2, bb-dd, 15,
aa/2, 0, 15,
-aa/2, 0, -1
!-----üvegosztó borda---------------
CUTPOLY 3,
-aa/2, bb,
-aa/2, bb-dd,
-aa/2+cc, bb
CUTPOLY 3,
aa/2, bb,
aa/2, bb-dd,
aa/2-cc, bb
dxo=(aa+tos)/(nx+1)
dyo=(bb+tos)/(ny+1)
ADD -aa/2,0,0.02
ADDX -tos
FOR j=1 to nx
ADDX dxo
BLOCK tos,b-2*ub,tov
NEXT j
DEL nx+1
FOR j=1 to nx+1
FOR i=1 to ny
ADDY dyo
BLOCK dxo-tos,tos,tov
NEXT i
DEL ny
ADDX dxo
NEXT j
CUTEND
CUTEND
!-----------------------------------
|
Luk definiálása az ablak számára
tok
a tokszelvény koordinátái
a tok szelvény trenszlációs pályája
KR* transzformáció a szárny forgástengelyébe
vasalat itt kezdődik
KR* transzformáció a henger (CYLIND) elhelyezéséhez
a pipapánt anyagának beállítása
egy pipapánt (henger) elhelyezése
KR* eltolása
másik pipapánt (henger) elhelyezése
a legutolsó 3 KR* transzformáció törlése
a szárny anyagának beállítása
szárny nyitásszögének megfelelő KR* transzformáció
a szárny szelvényének koordinátái
a szárny szelvényének trenszlációs pályája
üvegezés
üvegezés szélének távolsága a külső széltől
a lesarkítás függőlegessel bezárt szöge
az üveg szélessége
az üveg magassága
az üveg lesarkítása x
az üveg lesarkítása y
KR* eltolása az üvegezés síkjára
KR* eltolása az üveg aljára
az üveg "leírása"
az üvegosztó (ál)bordák
definiálunk két vágópoligont, amivel a
a kilógó bordákat levágjuk
|
